*******************************************************************************
* keyboard.device.S  Written by Readysoft.
* Copyright 1992,1993,1994 RS.  All rights reserved.  1992.06.08.-1994.05.18.
* v1.24.
*******************************************************************************

*******************************************************************************
* Macros
*******************************************************************************

;------------------------------------------------------------------------------
; KeyboradName Macro
;------------------------------------------------------------------------------
KBD.NAM		MACRO
		DC.B	'keyboard.device',0
		EVEN
		ENDM

*******************************************************************************
* DEV Macro
*******************************************************************************

KBD.DEV		MACRO

*******************************************************************************
* Constant Definitions
*******************************************************************************

;------------------------------------------------------------------------------
; Direction Bit Definitions
;------------------------------------------------------------------------------
kbd_di_b_U	EQU	0				up
kbd_di_b_D	EQU	1				down
kbd_di_b_R	EQU	2				right
kbd_di_b_L	EQU	3				left

;------------------------------------------------------------------------------
; Direction Definitions
;------------------------------------------------------------------------------
kbd_di_No	EQU	0
kbd_di_U	EQU	1<<kbd_di_b_U			up
kbd_di_D	EQU	1<<kbd_di_b_D			down
kbd_di_R	EQU	1<<kbd_di_b_R			right
kbd_di_L	EQU	1<<kbd_di_b_L			left
kbd_di_UR	EQU	kbd_di_U+kbd_di_R		up-right
kbd_di_UL	EQU	kbd_di_U+kbd_di_L		up-left
kbd_di_DR	EQU	kbd_di_D+kbd_di_R		down-right
kbd_di_DL	EQU	kbd_di_D+kbd_di_L		down-left
kbd_di_Up	EQU	kbd_di_U
kbd_di_Down	EQU	kbd_di_D
kbd_di_Right	EQU	kbd_di_R
kbd_di_Left	EQU	kbd_di_L
kbd_di_Ext	EQU	-1

;------------------------------------------------------------------------------
; Status Definitions
;------------------------------------------------------------------------------
kbd_st_Pressed	EQU	1
kbd_st_Released	EQU	0

;------------------------------------------------------------------------------
; CIA Definitions
;------------------------------------------------------------------------------
kbd_SPEnable	EQU	cia_ICR_SC+cia_ICR_SP

;------------------------------------------------------------------------------
; Error Codes
;------------------------------------------------------------------------------
kbd_er_OK	EQU	$00000000			all right
kbd_er_UnDef	EQU	$8005ffff			undefined error

*******************************************************************************
* Varibles
*******************************************************************************
		RSRESET
kbd_Qualifiers	RS.B	1				shift,alt,etc..
kbd_ASCIICode	RS.B	1				last ascii code
kbd_RawCode	RS.B	1				last rawkey code
kbd_NU		RS.B	1				not used
kbd_KeyMap	RS.B	16				bit is set when pressed
kbd_SizeOf	RS.B	0

*******************************************************************************
* Routine Offsets
*******************************************************************************
		RSRESET
		RS.B	-6
kbd_Init	RS.B	-6
kbd_Interrupt2	RS.B	-6
kbd_ReadKey	RS.B	-6
kbd_TestKey	RS.B	-6
kbd_AskCrsrKeys	RS.B	-6

*******************************************************************************
* Code
*******************************************************************************
		jmp	kbd.AskCrsrKeys
		jmp	kbd.TestKey
		jmp	kbd.ReadKey
		jmp	kbd.Interrupt2
		jmp	kbd.Init

keyboard.dev	BLK.B	kbd_SizeOf,0
		EVEN

;------------------------------------------------------------------------------
; Init		NoOp
;------------------------------------------------------------------------------
kbd.Init	movem.l	d0/a0/a5,-(a7)
		lea	keyboard.dev(pc),a5
		move.l	a5,a0				clear varible area
		move.w	#kbd_SizeOf-1,d0
.Clear		clr.b	(a0)+
		dbf	d0,.Clear
		bclr	#cia_CRA_b_SPM,cia_ACRA		SP input
		move.b	#kbd_SPEnable,cia_AICR		SP interrupt enabled
		movem.l	(a7)+,d0/a0/a5
		rts

;------------------------------------------------------------------------------
; Interrupt2	CIAAICR(d0)
;------------------------------------------------------------------------------
kbd.Interrupt2	movem.l	d0-d2/a0/a5,-(a7)
		lea	keyboard.dev(pc),a5
		btst	#cia_ICR_b_SP,d0		serial port interrupt ?
		beq	.Exit
		moveq	#0,d0
		moveq	#0,d1
		move.b	cia_ASDR,d0			rawkey code in SDR
		move.b	d0,kbd_RawCode(a5)		store rawkey code
		move.b	d0,d1
		bset	#cia_CRA_b_SPM,cia_ACRA		set CRA.SPMODE
		not.b	d0
		lsr.b	#1,d0				key number
		moveq	#0,d2
		move.b	d0,d2
		lsr.b	#3,d2
		eor.b	#$0f,d2
		bclr	#cia_CRA_b_SPM,cia_ACRA		clear CRA.SPMODE
		btst	#0,d1				released when 0
		beq.s	.KeyUp
		lea	kbd_KeyMap(a5),a0
		bset	d0,0(a0,d2.w)
		cmpi.b	#$60,d0				qualifiers over $60
		bmi.s	.Normal
		bset	d0,kbd_Qualifiers(a5)
		bra	.Exit
.Normal		moveq	#0,d1
		move.b	kbd_Qualifiers(a5),d1		qualifiers
		btst	#0,d1				left shift
		bne	.Shift
		btst	#1,d1				right shift
		bne	.Shift
		btst	#2,d1				caps lock
		bne	.Caps
		lea	kbd.Key(pc),a0			no shift
		bra.s	.TableOK
.Shift		lea	kbd.KeySH(pc),a0
		bra.s	.TableOK
.Caps		lea	kbd.KeyCS(pc),a0
		bra.w	.TableOK
.TableOK	move.b	0(a0,d0.w),d0			ASCII code
		move.b	d0,kbd_ASCIICode(a5)
		bra	.Exit
.KeyUp		lea	kbd_KeyMap(a5),a0
		bclr	d0,0(a0,d2.w)
		cmpi.w	#$60,d0				qualifiers over $60
		bmi.s	.Exit
		bclr	d0,kbd_Qualifiers(a5)
.Exit		movem.l	(a7)+,d0-d2/a0/a5
		rts

;------------------------------------------------------------------------------
; ReadKey	NoOp --> ASCIICode(d0)
;------------------------------------------------------------------------------
kbd.ReadKey	move.l	a5,-(a7)
		lea	keyboard.dev(pc),a5
		moveq	#0,d0
		move.b	kbd_ASCIICode(a5),d0
		clr.b	kbd_ASCIICode(a5)
		move.l	(a7)+,a5
		rts

;------------------------------------------------------------------------------
; TestKey	KeyCode(d0) --> Status(d0)
;------------------------------------------------------------------------------
kbd.TestKey	movem.l	d1-d2/a0/a5,-(a7)
		lea	keyboard.dev(pc),a5
		move.l	d0,d1
		moveq	#0,d2
		move.b	d1,d2
		lsr.b	#3,d2
		eor.b	#$0f,d2
		lea	kbd_KeyMap(a5),a0
		moveq	#kbd_st_Released,d0
		btst	d1,0(a0,d2.w)			pressed ?
		beq.s	.Released
		moveq	#kbd_st_Pressed,d0
.Released	movem.l	(a7)+,d1-d2/a0/a5
		rts

;------------------------------------------------------------------------------
; AskCrsrKeys	NoOp --> dX,dY,Direction,Fire(d0,d1,d2,d3)
;------------------------------------------------------------------------------
kbd.AskCrsrKeys	movem.l	a0/a5,-(a7)
		lea	keyboard.dev(pc),a5
		moveq	#0,d2
		move.b	kbd_KeyMap+6(a5),d2		Cursor keys ?
		lsr.b	#4,d2				bit $4c-$4f
		lea	kbd.DirData(pc),a0
		move.b	0(a0,d2.w),d2
		moveq	#$61,d0
		bsr	kbd.TestKey			Fire : RShift
		move.l	d0,d3
		bsr	kbd.CalcdXY
		movem.l	(a7)+,a0/a5
		rts

*******************************************************************************
* Private Routines
*******************************************************************************

;------------------------------------------------------------------------------
; CalcdXY	Direction(d2) --> dX,dY(d0,d1)
;------------------------------------------------------------------------------
kbd.CalcdXY	cmpi.b	#kbd_di_Up,d2
		beq.s	.Up
		cmpi.b	#kbd_di_Down,d2
		beq.s	.Down
		cmpi.b	#kbd_di_Left,d2
		beq.s	.Left
		cmpi.b	#kbd_di_Right,d2
		beq.s	.Right
		moveq	#0,d0
		moveq	#0,d1
		bra.s	.Exit
.Up		moveq	#0,d0
		moveq	#-1,d1
		bra.s	.Exit
.Down		moveq	#0,d0
		moveq	#1,d1
		bra.s	.Exit
.Left		moveq	#-1,d0
		moveq	#0,d1
		bra.s	.Exit
.Right		moveq	#1,d0
		moveq	#0,d1
.Exit		rts

*******************************************************************************
* DataArea
*******************************************************************************
kbd.Key		DC.B	" 1234567890߸",92,0,"0"
		DC.B	"qwertzuiopü+",0,"123"
		DC.B	"asdfghjklöá#",0,"456"
		DC.B	"<yxcvbnm,.-",0,".789"
		DC.B	" ",8,9,10,10,27,127,0
		DC.B	0,0,"-",0,28,29,30,31
		DC.B	$80,$81,$82,$83,$84,$85,$86,$87
		DC.B	$88,$89,0,0,0,0,0,0

kbd.KeySH	DC.B	"~!",34,"§$%&/()=?´¦",0
		DC.B	"0","QWERTZUIOPÜ*",0,"123"
		DC.B	"ASDFGHJKLÖÁ^",0,"456"
		DC.B	">YXCVBNM;:_",0,".789"
		DC.B	" ",8,9,10,10,27,127,0,0
		DC.B	0,"-",0,28,29,30,31
		DC.B	$80,$81,$82,$83,$84,$85,$86,$87
		DC.B	$88,$89,0,0,0,0,0,0

kbd.KeyCS	DC.B	"`1234567890߸",92,0,"0"
		DC.B	"QWERTZUIOPü+",0,"123"
		DC.B	"ASDFGHJKLöá#",0,"456"
		DC.B	"<YXCVBNM,.-",0,".789"
		DC.B	" ",8,9,10,10,27,127,0,0
		DC.B	0,"-",0,28,29,30,31
		DC.B	$80,$81,$82,$83,$84,$85,$86,$87
		DC.B	$88,$89,0,0,0,0,0,0

kbd.DirData	DC.B	kbd_di_No,kbd_di_U
		DC.B	kbd_di_D,kbd_di_No
		DC.B	kbd_di_R,kbd_di_UR
		DC.B	kbd_di_DR,kbd_di_R
		DC.B	kbd_di_L,kbd_di_UL
		DC.B	kbd_di_DL,kbd_di_L
		DC.B	kbd_di_No,kbd_di_U
		DC.B	kbd_di_D,kbd_di_No

		ENDM